Sub Process_Globals
' Juan Antonio Villalpando
' juana1991@yahoo.com
' marzo 2013
   Dim archivo_pdf As PDFWriter
   Dim tamanno_papel As PDFPaperSizes
   Dim fuente As PDFStandardFonts
End Sub

Sub Globals
   Dim boton1, boton2 As Button
   Dim contenido As String
End Sub

Sub Activity_Create(FirstTime As Boolean)
    ' Crea Botón1 (Button)
    boton1.Initialize("boton1")
    boton1.TextColor = Colors.Red
    boton1.Text = "Pulsa para crear el pdf"
    Activity.AddView(boton1, 0dip, 10dip, 100%x, 10%y)
    
    ' Crea Botón2 (Button)
    boton2.Initialize("boton2")
    boton2.TextColor = Colors.Red
    boton2.Text = "Pulsa para ver el pdf"
    Activity.AddView(boton2, 0dip, 40dip, 100%x, 10%y)
End Sub

Sub Activity_Resume

End Sub

Sub Activity_Pause (UserClosed As Boolean)

End Sub

Sub boton1_Click
   ' Creación del archivo PDF
   If File.Exists(File.DirRootExternal,"ejemplo.pdf") Then File.Delete(File.DirRootExternal,"ejemplo.pdf")
   archivo_pdf.Initialize("Evento_PDF",tamanno_papel.A4_WIDTH, tamanno_papel.A4_HEIGHT)
   ' Añade una línea de texto y una raya
   archivo_pdf.setFont(fuente.SUBTYPE, fuente.COURIER_BOLD )
   archivo_pdf.addText(20,600,10,"Juan Antonio Villalpando.")
   archivo_pdf.addLine(20,615,500,615)
   ' Añade otra línea de texto y una raya
   archivo_pdf.setFont2(fuente.SUBTYPE, fuente.COURIER, fuente.WIN_ANSI_ENCODING)
   archivo_pdf.addText(20,550,10,"juana1991@yahoo.com")
   archivo_pdf.addLine(20,520,500,520)
   ' Añade un recuadro
   archivo_pdf.addRectangle(10, 680, 280, 150)
   ' Crea el archivo PDF
   archivo_pdf.ConverseDocument
   archivo_pdf.outputToFile(File.DirRootExternal, "ejemplo.pdf",contenido,"ISO-8859-1")
End Sub

Sub boton2_Click
   ' Lectura del archivo PDF
   If File.Exists(File.DirRootExternal,"ejemplo.pdf") Then
      Dim inte As Intent
      Try
         inte.Initialize(inte.ACTION_VIEW, "file:" & File.DirRootExternal & "/ejemplo.pdf")
         inte.SetType("application/pdf")
         Try
            StartActivity(inte)
         Catch
            ToastMessageShow("Error al abrir.", True)
         End Try
      Catch
         Return
      End Try
   End If
End Sub

Sub Evento_PDF_ConversionDone(Content As String)
contenido = Content
ProgressDialogHide
End Sub