|
Tutorial del Internet de las Cosas con el ESP8266
Juan Antonio Villalpando
Volver al índice del tutorial
____________________________
319.- ESP8266 D1 R2. Crear Punto de Acceso. Encender/apagar un LED mediante un Botón.
- Fíjate que el nombre y contraseña de la red NO es la de nuestro Router, es un nombre y contraseña de la red que queramos crear.
- En mi caso he puesto la red Juan y la contraseña 123456789, puedes poner otra.
- En este caso nuestro dispositivo NO está conectado a nuestro Router ni a Internet.
- Es un Punto de Acceso independiente de nuestro Router.
- Ve al Monitor Serie, en mi caso ha creado la red: 192.168.4.1
- Si en un navegador escribimos esa IP, conectaremos con nuestro Punto de Acceso.
- Pero ATENCIÓN, observa que la red creada es la 192.168.4.X, en cambio la red de nuestro Router es 192.168.1.X
- Son redes distintas, así que en principio desde nuestro ordenador conectado a nuestro Router no podemos entrar en la página 192.168.4.1
- Necesitamos que el ordenador esté en la misma Red WiFi.
- Para probarlo es mejor utilizar nuestro móvil que tiene WiFi.
- Vamos a nuestro móvil. Ajustes. WiFi. Localizamos la Red "Juan", escribimos la contraseña "123456789" y conectamos con el Punto de Acceso que hemos creado.
- Para que funcione el Punto de acceso, es mejor quitar la parte correspondiente a la IP estática.
punto_acceso_BotónLED.ino |
// Juan A. Villalpando.
// KIO4.COM
// Punto de acceso.
#include <ESP8266WiFi.h>
// Configuración de la IP estática.
IPAddress local_IP(192,168,4,2);
IPAddress gateway(192,168,4,9);
IPAddress subnet(255,255,255,0);
const char* ssid = "Juan";
const char* password = "123456789";
WiFiServer server(80);
#define LED5 D5 // LED en terminal 5
String estado = "";
void setup() {
Serial.begin(115200);
pinMode(LED5, OUTPUT);
// Configuración del Punto de Acceso.
Serial.println();
Serial.print("Configurando IP Estática: ");
Serial.println(WiFi.softAPConfig(local_IP, gateway, subnet) ? "Establecida IP estática" : "Error IP");
Serial.print("Configurando Punto de Acceso: ");
Serial.println(WiFi.softAP(ssid, password) ? ssid : "Error creación P.A.");
// Esta es la IP
Serial.print("Esta es la IP para conectar: ");
Serial.print("http://");
Serial.println(WiFi.softAPIP());
// Inicio del Servidor web.
server.begin();
Serial.println("Servidor web iniciado.");
}
void loop() {
// Consulta si se ha conectado algún cliente.
WiFiClient client = server.available();
if (!client) {
return;
}
Serial.print("Nuevo cliente: ");
Serial.println(client.remoteIP());
// Espera hasta que el cliente envíe datos.
while(!client.available()){ delay(1); }
/////////////////////////////////////////////////////
// Lee la información enviada por el cliente.
String req = client.readStringUntil('\r');
Serial.println(req);
// Realiza la petición del cliente.
if (req.indexOf("on5") != -1) {digitalWrite(LED5, HIGH); estado = "Encendido";}
if (req.indexOf("off5") != -1){digitalWrite(LED5, LOW); estado = "Apagado";}
//////////////////////////////////////////////
// Página WEB. ////////////////////////////
client.println("HTTP/1.1 200 OK");
client.println("Content-Type: text/html");
client.println(""); // Importante.
client.println("<!DOCTYPE HTML>");
client.println("<html>");
client.println("<head><meta charset=utf-8></head>");
client.println("<body><center><font face='Arial'>");
client.println("<h1>Servidor web con ESP8266.</h1>");
client.println("<h2><font color='#009900'>KIO4.COM - Juan A. Villalpando</font></h2>");
client.println("<h3>Página web.</h3>");
client.println("<br><br>");
client.println("<img src='http://iesromerovargas.com/kio42.png'><br>");
client.println("<a href='on5'><button>Enciende LED5</button></a>");
client.println("<a href='off5'><button>Apaga LED5</button></a>");
client.println("<br><br>");
client.println(estado);
client.println("</font></center></body></html>");
Serial.print("Cliente desconectado: ");
Serial.println(client.remoteIP());
client.flush();
client.stop();
}
|
______________________________________________________
- Comentarios.
1.- Instala esta aplicación en tu móvil para ver el nivel con el que el Punto de Acceso llega.
2.- Podemos cambiar el canal de transmisión del Punto de Acceso, de esta manera:
WiFi.softAP(ssid, password, 10);
3.- Para ocultar la red podemos poner:
WiFi.softAP(ssid, password, 10, 0);
4.- Red sin clave:
WiFi.softAP(ssid);
5.- Mediante esta orden podemos ver el número de dispositivos conectados a nuestro Punto de Acceso, el máximo es 5.
WiFi.softAPgetStationNum()
6.- Desconectar un cliente.
WiFi.softAPdisconnect();
- Canal muy saturado. Analizador de WiFi.
- Instalamos en nuestro móvil esta aplicación de la Play Store de Google:
WiFi Analyzer
- Observamos los WiFi que hay en nuestra proximidad.
- Puede ocurrir que en el mismo canal "convivan" muchos WiFi, en este caso sería conveniente cambiar el canal de nuestro WiFi mediante la orden que acabamos de ver: WiFi.softAP(ssid, password, 10);
- Si en el mismo canal "conviven" muchos WiFi será un canal saturado y la red se enlentecerá, incluso se bloqueará. |
 |
_________________________________
- Propuestas.
1.- Establece que el Punto de acceso tenga cierta IP.
2.- Crea un tercer Botón llamado "Ver estado", que cuando lo pulses obtenga el estado del LED sin modificarlo.
3.- Conecta otro LED en otro terminal.
____________________________________________________________
- Otro ejemplo.
- Crea un punto de acceso y una latitud y longitud aleatorios.
- IP = 192.168.4.1
punto_acceso_2.ino |
// Juan A. Villalpando.
// KIO4.COM
// Punto de acceso.
#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>
const char* host = "Mi_host";
const char* ssid = "RedESP8266";
String latitude, longitude;
ESP8266WebServer server(80);
void setup() {
Serial.begin(115200);
// Connecting WiFi
WiFi.mode(WIFI_AP);
WiFi.softAP(ssid);
// Starting WEB-server
server.on ( "/", HTTP_handleRoot );
server.onNotFound ( HTTP_handleRoot );
server.begin();
}
void loop() {
server.handleClient();
delay(50);
latitude = "Latitud = " + (String) random(1,90);
longitude = "Longitud = " + (String) random(-90,-1);
}
void HTTP_handleRoot(void) {
server.send(200, "text/plain", latitude + "," + longitude);
if( server.hasArg("State") ){
Serial.println(server.arg("State"));
}
server.send(200,"text/html","" );
}
|
- App Inventor.
______________________________________________________
- Cambiar la IP:
https://github.com/esp8266/Arduino/issues/2208
_______________________________
|
