// Juan A. Villalpando.
// KIO4.COM
// Pone los LED12 y LED13 en alto o bajo.
// Consulta el estado de los pulsadores.

////////////// Screen LCD I2C ///////////////
#include <LiquidCrystal_I2C.h>
int columnas = 16;
int filas = 2;
LiquidCrystal_I2C lcd(0x27, columnas, filas);  
// LiquidCrystal_I2C lcd(0x3F, columnas, filas); 
////////////////////////////////////////////////
#include <WiFi.h>
 
const char* ssid = "Nombre_de_tu_red_wifi";
const char* password = "La_clave_de_tu_red_wifi";

#define LED12  12    // LED en terminal 12
#define LED13  13    // LED en terminal 12
#define pulsa16 16   // Pulsador en terminal 16.
#define pulsa17 17   // Pulsador en terminal 17.
int valor16;
int valor17;
String d12;
String d13;
String p16;
String p17;
String todos = "0,0,0,0";
String frase = "-";

WiFiServer server(80);
 
void setup() {
  lcd.init();      // Screen LCD                    
  lcd.backlight(); // Screen LCD
  Serial.begin(115200);
  pinMode(LED12, OUTPUT);
  pinMode(LED13, OUTPUT);
  pinMode(pulsa16, INPUT);
  pinMode(pulsa17, INPUT);
  
// Conecta a la red wifi.
  Serial.println();
  Serial.print("Conectando con ");
  Serial.println(ssid);
 
  WiFi.begin(ssid, password);
 
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("Conectado con WiFi.");
 
  // Inicio del Servidor web.
  server.begin();
  Serial.println("Servidor web iniciado.");
 
  // Esta es la IP
  Serial.print("Esta es la IP para conectar: ");
  Serial.print("http://");
  Serial.println(WiFi.localIP());
}
 
void loop() {
  // Consulta si se ha conectado algún cliente.
  WiFiClient client = server.available();
  if (!client) {
    return;
  }
  
  Serial.print("Nuevo cliente: ");
  Serial.println(client.remoteIP());
 
  // Espera hasta que el cliente envíe datos.
  while(!client.available()){ delay(1); }

/////////////////////////////////////////////////////
// Lee la información enviada por el cliente.
String req = client.readStringUntil('\r');
Serial.println(req);

// Realiza la petición del cliente.
     if (req.indexOf("on12") != -1) {digitalWrite(LED12, HIGH);}
else if (req.indexOf("off12") != -1){digitalWrite(LED12, LOW);}
else if (req.indexOf("on13") != -1) {digitalWrite(LED13, HIGH);}
else if (req.indexOf("off13") != -1){digitalWrite(LED13, LOW);}

else if (req.indexOf("consulta") != -1){consulta();}
else if (req.indexOf("lcd") != -1)
{
 // GET /lcdEstoestexto. 
 frase = req.substring(8);          // el mensaje comienza en el caracter 8.
 frase.replace("+", " ");           // Para que los espacios no salgan con +
 frase.replace(" HTTP/1.1", " ");   // Para quitar HTTP/1.1 
 escribe_lcd();
} else {
Serial.println("Error.");
}

//////////////////////////////////////////////
  // Página WEB. ////////////////////////////
  client.println("HTTP/1.1 200 OK");
  client.println("Content-Type: text/html");
  client.println(""); //  Importante.
  client.println(todos);
  
  Serial.print("Cliente desconectado: ");
  Serial.println(client.remoteIP());
  client.flush();
  client.stop();
}

// Consulta el estado de los elementos.
void consulta(){
   if(digitalRead(LED12) == HIGH) {d12 = "LED12 encendido.";} else {d12 = "LED12 apagado.";}
   if(digitalRead(LED13) == HIGH) {d13 = "LED13 encendido.";} else {d13 = "LED13 apagado.";}
 valor16 = digitalRead(pulsa16);
   if (valor16 == HIGH) {p16 = "Pulsador16 PULSADO";} else {p16 = "Pulsador16 NO pulsado";}
 valor17 = digitalRead(pulsa17);
   if (valor17 == HIGH) {p17 = "Pulsador17 PULSADO";} else {p17 = "Pulsador17 NO pulsado";}
  
 todos = d12 + "," + d13 + "," + p16 + "," + p17;
 Serial.println(todos);
 delay(10);
}

// Pantalla LCD
void escribe_lcd(){
  lcd.clear(); // Borra pantalla.
  lcd.setCursor(0, 0); // Inicio del cursor
  lcd.print(frase);
  lcd.setCursor(0,1); // Siguiente renglón.
  lcd.print("KIO4.COM");
  Serial.println(frase);
}