// Juan A. Villalpando.
// KIO4.COM
// Sensor humedad temperatura
// WiFi LCD

////////////// Screen LCD I2C ///////////////
#include <LiquidCrystal_I2C.h>
int columnas = 16;
int filas = 2;
LiquidCrystal_I2C lcd(0x27, columnas, filas);  
// LiquidCrystal_I2C lcd(0x3F, columnas, filas); 
////////////////////////////////////////////////
#include "DHT.h" 
#define DHTPIN 25 
#define DHTTYPE DHT11 
DHT dht(DHTPIN, DHTTYPE);
int humedad_old = 50;
int temperatura_old = 21;
//////////////////////////////////////////////
#include <WiFi.h>
 
const char* ssid     = "Nombre_de_tu_red_wifi";
const char* password = "La_clave_de_tu_red_wifi";

// Configuración de la IP estática.
    IPAddress local_IP(192, 168, 1, 12);
    IPAddress gateway(192, 168, 1, 1);
    IPAddress subnet(255, 255, 255, 0); 
    IPAddress primaryDNS(8, 8, 8, 8); //opcional 
    IPAddress secondaryDNS(8, 8, 4, 4); //opcional 

WiFiServer server(80);
 
void setup() {
  lcd.init();      // Screen LCD                    
  lcd.backlight(); // Screen LCD
  Serial.begin(115200);
  dht.begin(); // Sensor humedad-temperatura.
  
// Establecimiento de la IP estática.
   if (!WiFi.config(local_IP, gateway, subnet, primaryDNS, secondaryDNS)) {
   Serial.println("Fallo en la configuración.");
   }

// Conecta a la red wifi.
  Serial.println();
  Serial.print("Conectando con ");
  Serial.println(ssid);
 
  WiFi.begin(ssid, password);
 
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("Conectado con WiFi.");
 
  // Inicio del Servidor web.
  server.begin();
  Serial.println("Servidor web iniciado.");
 
  // Esta es la IP
  Serial.print("Esta es la IP para conectar: ");
  Serial.print("http://");
  Serial.println(WiFi.localIP());
}
 
void loop() {
// Lee humedad y temperatura y presenta en LCD.
int humedad = dht.readHumidity();
int temperatura = dht.readTemperature();
// Esto es para evitar el parpadeo:
if (humedad != humedad_old || temperatura != temperatura_old) { 
    humedad_old = humedad;
    temperatura_old = temperatura;
lcd.clear(); // Borra pantalla
lcd.setCursor(0,0); // Inicio del cursor
lcd.print("Humedad = ");
lcd.print(humedad);
lcd.setCursor(0,1); // Siguiente renglón.
lcd.print("Temper. = ");
lcd.print(temperatura);
}
 /////////////////////////////////////////////////////
 // Consulta si se ha conectado algún cliente.
  WiFiClient client = server.available();
  if (!client) {
   return;
  }
   
  Serial.print("Nuevo cliente: ");
  Serial.println(client.remoteIP());

  // Espera hasta que el cliente envíe datos.
  while(!client.available()){ delay(1); }

// Lee la información enviada por el cliente.
String req = client.readStringUntil('\r');
Serial.println(req);

//////////////////////////////////////////////
  // Página WEB. //////////////////////////// 
  client.println("HTTP/1.1 200 OK");
  client.println("Content-Type: text/html");
  client.println(""); //  Importante.
  client.print(humedad);
  client.print(",");
  client.print(temperatura);
  
  Serial.print("Cliente desconectado: ");
  Serial.println(client.remoteIP());
  client.flush();
  client.stop();
}