|
Tutorial del Internet de las Cosas y Bluetooth con el ESP32
Juan Antonio Villalpando
Volver al índice del tutorial
____________________________
122.- Wemos D1 R32 ESP32. Punto de Acceso y Estación de un Router. Servidor Web.
- Vamos a configurar a nuestro ESP32 como un Servidor Web con una página que apague y encienda un LED, el ESP32 será una Estación de nuestro Router, es decir está vinculado a nuestro Router con una IP de tipo 192.168.1.X
- Además el ESP32 lo vamos a configurar como Punto de Acceso, es decir, creará un red de tipo 192.168.4.X
- El Servidor Web se verá tanto desde la red del Router como desde la red del Punto de Acceso creado por el ESP32.
punto_acceso_estacion.ino |
// Juan A. Villalpando.
// KIO4.COM
// Creación de un Punto de Acceso.
// Servidor Web.
// Estación de un Router.
#include <WiFi.h>
#include <WiFiClient.h>
#include <WiFiAP.h>
const char* ssid = "Juan";
const char* password = "123456789";
const char * ssid2 = "Nombre_de_tu_red_Wifi";
const char * password2 = "La_clave_de_la_red_Wifi";
WiFiServer server(80);
#define LED2 2 // LED en terminal 2
String estado = "";
void setup() {
Serial.begin(115200);
pinMode(LED2, OUTPUT);
// Crea un Punto de Acceso.
Serial.println();
Serial.print("Configurando Punto de Acceso: ");
Serial.println(ssid);
WiFi.softAP(ssid, password);
IPAddress myIP = WiFi.softAPIP();
// Esta es la IP
Serial.print("IP para conectar al Punto de Acceso: ");
Serial.print("http://");
Serial.println(myIP);
// Inicio del Servidor web.
server.begin();
Serial.println("Servidor web iniciado.");
// Conecta con mi Router
WiFi.begin(ssid2, password2);
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(".");
}
Serial.println("Conectado con WiFi del Router");
// Esta es la IP
Serial.print("IP para conectar desde la red del Router.");
Serial.print("http://");
Serial.println(WiFi.localIP());
//////////////////////////////////////////
}
void loop() {
// Consulta si se ha conectado algún cliente.
WiFiClient client = server.available();
if (!client) {
return;
}
Serial.print("Nuevo cliente: ");
Serial.println(client.remoteIP());
// Espera hasta que el cliente envíe datos.
while(!client.available()){ delay(1); }
/////////////////////////////////////////////////////
// Lee la información enviada por el cliente.
String req = client.readStringUntil('\r');
Serial.println(req);
// Realiza la petición del cliente.
if (req.indexOf("on2") != -1) {digitalWrite(LED2, HIGH); estado = "Encendido";}
if (req.indexOf("off2") != -1){digitalWrite(LED2, LOW); estado = "Apagado";}
//////////////////////////////////////////////
// Página WEB. ////////////////////////////
client.println("HTTP/1.1 200 OK");
client.println("Content-Type: text/html");
client.println(""); // Importante.
client.println("<!DOCTYPE HTML>");
client.println("<html>");
client.println("<head><meta charset=utf-8></head>");
client.println("<body><center><font face='Arial'>");
client.println("<h1>Servidor web con ESP32.</h1>");
client.println("<h2><font color='#009900'>KIO4.COM - Juan A. Villalpando</font></h2>");
client.println("<h3>Página web.</h3>");
client.println("<br><br>");
client.println("<img src='http://iesromerovargas.com/kio42.png'><br>");
client.println("<a href='on2'><button>Enciende LED2</button></a>");
client.println("<a href='off2'><button>Apaga LED2</button></a>");
client.println("<br><br>");
client.println(estado);
client.println("</font></center></body></html>");
Serial.print("Cliente desconectado: ");
Serial.println(client.remoteIP());
client.flush();
client.stop();
}
|
_______________________________
|
