|
Tutorial del Internet de las Cosas y Bluetooth con el ESP32
Juan Antonio Villalpando
Volver al índice del tutorial
____________________________
109.- Wemos D1 R32 ESP32. Servidor web. Página web. Botón y LED.
_________________________________
5.- Servidor Web. Enciende/apaga un LED mediante un Botón.
- Se muestra una página web con dos Botones, con uno encendemos el LED2 y con el otro lo apagamos.
- También nos mostrará el estado del LED2.
webserver_botones_led.ino |
// Juan A. Villalpando.
// KIO4.COM
// Enciende y apaga LED. Botones.
#include <WiFi.h>
const char* ssid = "Nombre_de_tu_red_wifi";
const char* password = "La_clave_de_tu_red_wifi";
WiFiServer server(80);
#define LED2 2 // LED en terminal 2
String estado = "";
void setup() {
Serial.begin(115200);
pinMode(LED2, OUTPUT);
// Conecta a la red wifi.
Serial.println();
Serial.print("Conectando con ");
Serial.println(ssid);
WiFi.begin(ssid, password);
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(".");
}
Serial.println("Conectado con WiFi.");
// Inicio del Servidor web.
server.begin();
Serial.println("Servidor web iniciado.");
// Esta es la IP
Serial.print("Esta es la IP para conectar: ");
Serial.print("http://");
Serial.println(WiFi.localIP());
}
void loop() {
// Consulta si se ha conectado algún cliente.
WiFiClient client = server.available();
if (!client) {
return;
}
Serial.print("Nuevo cliente: ");
Serial.println(client.remoteIP());
// Espera hasta que el cliente envíe datos.
while(!client.available()){ delay(1); }
/////////////////////////////////////////////////////
// Lee la información enviada por el cliente.
String req = client.readStringUntil('\r');
Serial.println(req);
// Realiza la petición del cliente.
if (req.indexOf("on2") != -1) {digitalWrite(LED2, HIGH); estado = "Encendido";}
if (req.indexOf("off2") != -1){digitalWrite(LED2, LOW); estado = "Apagado";}
//////////////////////////////////////////////
// Página WEB. ////////////////////////////
client.println("HTTP/1.1 200 OK");
client.println("Content-Type: text/html");
client.println(""); // Importante.
client.println("<!DOCTYPE HTML>");
client.println("<html>");
client.println("<head><meta charset=utf-8></head>");
client.println("<body><center><font face='Arial'>");
client.println("<h1>Servidor web con ESP32.</h1>");
client.println("<h2><font color='#009900'>KIO4.COM - Juan A. Villalpando</font></h2>");
client.println("<h3>Página web.</h3>");
client.println("<br><br>");
client.println("<img src='http://iesromerovargas.com/kio42.png'><br>");
client.println("<a href='on2'><button>Enciende LED2</button></a>");
client.println("<a href='off2'><button>Apaga LED2</button></a>");
client.println("<br><br>");
client.println(estado);
client.println("</font></center></body></html>");
Serial.print("Cliente desconectado: ");
Serial.println(client.remoteIP());
client.flush();
client.stop();
}
|
_________________________________
- Propuestas.
1.- Comenta mediante doble barra //, las líneas indicadas.
- Observa que la página carga algo más rápida y sigue funcionando.
comenta estas líneas |
// Espera hasta que el cliente envíe datos.
// while(!client.available()){ delay(1); }
//////////////////////////////////////////////
// Página WEB. ////////////////////////////
// client.println("HTTP/1.1 200 OK");
// client.println("Content-Type: text/html");
// client.println(""); // Importante.
// client.println("<!DOCTYPE HTML>");
// client.println("<html>");
// client.println("<head><meta charset=utf-8></head>");
// client.println("<body><center><font face='Arial'>");
// client.println("<h1>Servidor web con ESP32.</h1>");
// client.println("<h2><font color='#009900'>KIO4.COM - Juan A. Villalpando</font></h2>");
// client.println("<h3>Página web.</h3>");
// client.println("<br><br>");
// client.println("<img src='http://iesromerovargas.com/kio42.png'><br>");
client.println("<a href='on2'><button>Enciende LED2</button></a>");
client.println("<a href='off2'><button>Apaga LED2</button></a>");
client.println("<br><br>");
client.println(estado);
// client.println("</font></center></body></html>");
Serial.print("Cliente desconectado: ");
Serial.println(client.remoteIP());
client.flush();
client.stop();
}
|
2.- Crea un tercer Botón llamado "Ver estado", que cuando lo pulses obtenga el estado del LED sin modificarlo.
3.- Conecta otro LED en otro terminal.
if (req.indexOf("consulta") != -1){
if (digitalRead(LED2)){estado = "Encendido";}
else {estado = "Apagado";}
}
_______________________________
|
