// Juan A. Villalpando.
// KIO4.COM
// Pone los LED12 y LED13 en alto o bajo.
// Consulta el estado de los pulsadores.

////////////// Screen LCD I2C ///////////////
#include <LiquidCrystal_I2C.h>
int columnas = 16;
int filas = 2;
LiquidCrystal_I2C lcd(0x27, columnas, filas);  
// LiquidCrystal_I2C lcd(0x3F, columnas, filas); 
////////////////////////////////////////////////
#include "BluetoothSerial.h"

#if !defined(CONFIG_BT_ENABLED) || !defined(CONFIG_BLUEDROID_ENABLED)
#error Bluetooth no activado! Activa la conexion Bluetooth.
#endif

BluetoothSerial SerialBT;
 
#define LED12  12    // LED en terminal 12
#define LED13  13    // LED en terminal 12
#define pulsa16 16   // Pulsador en terminal 16.
#define pulsa17 17   // Pulsador en terminal 17.
int valor16;
int valor17;
String d12;
String d13;
String p16;
String p17;
String todos = "0,0,0,0";
String palabra = "-";

void setup() {
  lcd.init();      // Screen LCD                    
  lcd.backlight(); // Screen LCD
  Serial.begin(9600);
  pinMode(LED12, OUTPUT);
  pinMode(LED13, OUTPUT);
  pinMode(pulsa16, INPUT);
  pinMode(pulsa17, INPUT);
  
  SerialBT.begin("ESP32test");
}
 
void loop() {
 if(SerialBT.available()) {
     palabra = SerialBT.readStringUntil('\n');   

     // Realiza la peticion del cliente.
          if (palabra == "on12"){digitalWrite(LED12, HIGH);}
          if (palabra == "off12"){digitalWrite(LED12, LOW);}
          if (palabra == "on13"){digitalWrite(LED13, HIGH);}
          if (palabra == "off13"){digitalWrite(LED13, LOW);}
     
         if (palabra == "consulta"){consulta();}
         if (palabra.indexOf("lcd") != -1)
      {
      palabra = palabra.substring(3,palabra.length());
      escribe_lcd();
       }

} // Fin de available.
} // Fin de loop.

// Consulta el estado de los elementos.
void consulta(){
   if(digitalRead(LED12) == HIGH) {d12 = "LED12 encendido.";} else {d12 = "LED12 apagado.";}
   if(digitalRead(LED13) == HIGH) {d13 = "LED13 encendido.";} else {d13 = "LED13 apagado.";}
 valor16 = digitalRead(pulsa16);
   if (valor16 == HIGH) {p16 = "Pulsador16 PULSADO";} else {p16 = "Pulsador16 NO pulsado";}
 valor17 = digitalRead(pulsa17);
   if (valor17 == HIGH) {p17 = "Pulsador17 PULSADO";} else {p17 = "Pulsador17 NO pulsado";}
  
   todos = d12 + "," + d13 + "," + p16 + "," + p17 + "\n";
   SerialBT.print(todos);
   delay(10);
}

// Pantalla LCD
void escribe_lcd(){
  lcd.clear(); // Borra pantalla.
  lcd.setCursor(0, 0); // Inicio del cursor
  lcd.print(palabra);
  lcd.setCursor(0,1); // Siguiente renglón.
  lcd.print("KIO4.COM");
  Serial.println(palabra);
}