B4A en español - Juan Antonio Villalpando
(BASIC4Android)
-- Tutorial de B4A --
Volver al índice del tutorial
____________________________
65.- Colores Scroll.
- Presentación.
- En esta ocasión, disponemos de 3 Scrolls. Cuando los movemos cambia su Value desde 0 al 255 y el color y texto de su etiqueta correspondiente.
- En el casillero de abajo se realiza la suma de los tres colores.
Pantalla
|
|
________________________________
- Código.
- Aquí está el código. No tiene "Layout", todos los controles se crean en el código.
Copia y pega este código en un nuevo proyecto. |
Sub Process_Globals
' Juan Antonio Villalpando
' juana1991@yahoo.com ' marzo 2013 ' kio4.com
End Sub
Sub Globals
Dim scrollr, scrollv, scrolla As SeekBar
Dim etiquetar, etiquetav, etiquetaa, etiquetat As Label
Dim rojo, verde, azul As Int
End Sub
Sub Activity_Create(FirstTime As Boolean)
' Crea Scroll Rojo
scrollr.Initialize("scrollr")
scrollr.Max = 255
Activity.AddView(scrollr, 5dip, 10dip, 250dip, 30dip)
' Crea Scroll Verde
scrollv.Initialize("scrollv")
scrollv.Max = 255
Activity.AddView(scrollv, 5dip, 50dip, 250dip, 30dip)
' Crea Scroll Azul
scrolla.Initialize("scrolla")
scrolla.Max = 255
Activity.AddView(scrolla, 5dip, 90dip, 250dip, 30dip)
' Crea etiqueta Rojo
etiquetar.Initialize("etiqueta")
etiquetar.TextSize = 20
etiquetar.Gravity = Gravity.CENTER
etiquetar.TextColor = Colors.White
etiquetar.Color=Colors.Red
etiquetar.Text = "R"
Activity.AddView(etiquetar, 270dip, 5dip, 40dip, 40dip)
' Crea etiqueta Verde
etiquetav.Initialize("etiqueta")
etiquetav.TextSize = 20
etiquetav.Gravity = Gravity.CENTER
etiquetav.TextColor = Colors.White
etiquetav.Color=Colors.Green
etiquetav.Text = "V"
Activity.AddView(etiquetav, 270dip, 45dip, 40dip, 40dip)
' Crea etiqueta Azul
etiquetaa.Initialize("etiqueta")
etiquetaa.TextSize = 20
etiquetaa.Gravity = Gravity.CENTER
etiquetaa.TextColor = Colors.White
etiquetaa.Color=Colors.Blue
etiquetaa.Text = "A"
Activity.AddView(etiquetaa, 270dip, 85dip, 40dip, 40dip)
' Crea etiqueta Mezcla
etiquetat.Initialize("etiquetat")
etiquetat.TextSize = 20
etiquetat.Gravity = Gravity.CENTER
etiquetat.TextColor = Colors.White
etiquetat.Color=Colors.White
etiquetat.Text = ""
Activity.AddView(etiquetat, 5dip, 150dip, 300dip, 200dip)
End Sub
Sub Activity_Resume
End Sub
Sub Activity_Pause (UserClosed As Boolean)
End Sub
Sub scrollr_ValueChanged (Value As Int, UserChanged As Boolean)
rojo = Value
etiquetar.color = Colors.RGB(rojo, 0, 0)
etiquetar.Text = rojo
etiquetat.color = Colors.RGB(rojo, verde, azul)
End Sub
Sub scrollv_ValueChanged (Value As Int, UserChanged As Boolean)
verde = Value
etiquetav.color = Colors.RGB(0, verde, 0)
etiquetav.Text = verde
etiquetat.color = Colors.RGB(rojo, verde, azul)
End Sub
Sub scrolla_ValueChanged (Value As Int, UserChanged As Boolean)
azul = Value
etiquetaa.color = Colors.RGB(0, 0, azul)
etiquetaa.Text = azul
etiquetat.color = Colors.RGB(rojo, verde, azul)
End Sub
|
____________________________
- Mezcla de colores.
- Hay dos tipos de mezcla de colores: Aditiva y Substractiva.
La mezcla Aditiva es la que se utiliza en iluminación, focos, monitores, proyectores, luces,... consta de tres colores fundamentales Rojo, Verde y Azul. (RVA) en inglés (Red, Blue, Green - RGB).
- Si los tres colores tienen el valor de saturación su mezcla da el color Blanco.
- Si los colores tienen valores intermedios, obtenemos un tercer color que es la suma de los tres.
Mezcla aditiva RVA |
Mezcla substractiva CMY |
- La mezcla Substractiva es la que se utiliza en pigmentos, pinturas, impresoras, imprentas... consta de tres colores fundamentales Cian, Magenta y Amarillo. (CMA) en inglés (Cyan, Magenta, Yellow - CMY), también se le suele añadir el Negro (Black - K).
Si los tres colores tienen el valor de saturación su mezca da el color Negro.
Si los colores tienen valores intermedios, obtenemos un tercer color que es la resta de los tres.
- Véase también este tutorial de App Inventor: http://kio4.com/appinventor/20mezclacolores.htm
________________________________
|